10 REM **  THE  SEQUENCER  **
20 REM ** by  Dirk Tjossem **
30 REM **  Copyright 1982  **
40 REM INIT
50 OPTION BASE 0
60 DIM A%(2,9)
70 NUMDIG= 2
80 SOL$= "": INP$= SOL$
90 CLS
100 TRY= 0
110 PRINT "Play the game of"
120 PRINT "the Sequencer"
130 FORI=1 TO 1500: NEXT
140 CLS
150 PRINT "Enter a SEQUENCE of"
160 LPRINT: LPRINT "Enter a SEQUENCE of"
170 PRINT NUMDIG; "digits"
180 LPRINT NUMDIG; "digits"
190 LPRINT "No";SPC(NUMDIG);"WSQ CDP"
200 PRINT "No";SPC(NUMDIG);"WSQ CDP"
210 REM GENERATE SOLUTION
220 FOR I= 0 TO 9: A%(0,I)= 0: NEXT
230 RANDOMIZE VAL(RIGHT$(TIME$,2))
240 FOR I= 1 TO NUMDIG
250 SOL$= SOL$ + RIGHT$(STR$(INT(RND*10)),1)
260 NEXT
270 GOSUB 360
280 IF (CD<NUMDIG) AND (TRY<15) THEN 270
290 IF CD=NUMDIG THEN LPRINT "Success in";TRY;"tries":LPRINT: NUMDIG= NUMDIG + 1: GOTO 80
300 LPRINT TRY;"tries later..."
310 LPRINT"SOLUTION=";SOL$
320 PRINT TRY;"TRIES LATER..."
330 PRINT "Solution=";SOL$
340 FOR I= 1 TO 2000: NEXT
350 NUMDIG= NUMDIG - 1: GOTO 80
360 REM INPUT TRY
370 TRY= TRY + 1:FOR J=0 TO 2: FOR I= 0 TO 9: A%(J,I)=0: NEXT: NEXT
380 INP$= "":CD= 0: WS= 0
390 FOR I= 1 TO NUMDIG
400 X$= INKEY$
410 IF (X$<"0") OR (X$>"9") THEN 400
420 PRINT X$;
430 INP$= INP$ + X$
440 NEXT
450 REM DETERMINE # CORRECT DIGITS
460 FOR I= 1 TO NUMDIG
470 S= VAL(MID$(SOL$,I,1))
480 A%(0,S)= A%(0,S) + 1
490 E= VAL(MID$(INP$,I,1))
500 A%(1,E)= A%(1,E) + 1
510 IF S=E THEN CD=CD + 1: A%(2,S)= A%(2,S) + 1
520 NEXT
530 REM # DIGITS OUT OF SEQUENCE
540 FOR I=0 TO 9
550 WS= WS + A%(ABS(A%(0,I)>A%(1,I)),I) - A%(2,I)
560 NEXT
570 REM PRINT ROUTINE
580 LPRINT INP$;"  ";WS;" ";CD
590 PRINT "  ";WS;" ";CD
600 RETURN