10 REM******
20 REM* BOMBER
30 REM* WM V R SMITH
40 REM* ARTSCI INC
50 REM******
60 GOSUB 820:CLS
70 PX=2
80 LINE(0,30)-(110,30),PSET
90 GOSUB 180
100 GOSUB 360
110 IF BA=1 THEN GOSUB 520:GOTO90
120 IF INKEY$="" THEN90
130 BX=PX:BY=U+3
140 B=B+1
150 GOSUB 520
160 BA=1
170 GOTO90
180 PX=PX-2
190 IF PX<2   THEN 270
200 LINE(PX+7,U)-(PX+7,U+2),PRESET
210 LINE(PX+6,U)-(PX+6,U+2),PRESET
220 LINE(PX+5,U)-(PX+5,U+2),PSET
230 PSET(PX,U+2)
240 PSET(PX+1,U+2)
250 PSET(PX+4,U+1)
260 RETURN
270 LINE(PX,U+2)-(PX+7,U+2),PRESET
280 LINE(PX,U+1)-(PX+7,U+1),PRESET
290 PRESET(PX+7,U)
300 PX=100
310 U=INT((RND(1)* 50)/3)
320 IF U>23 THEN U=23
330 LINE(PX,U+2)-(PX+5,U+2),PSET
340 PSET(PX+4,U+1)
350 GOTO 180
360 TX=TX+1
370 IF TX>100 THEN 460
380 LINE(TX,27)-(TX,29),PRESET
390 PRESET(TX+1,27):PRESET(TX+1,29)
400 PRESET(TX+3,29)
410 PSET(TX+1,29)
420 PSET(TX+5,28)
430 PSET(TX+4,27)
440 PSET (TX+4,29)
450 RETURN
460 FOR S=27 TO 29
470 LINE(TX,S)-(TX+6,S),PRESET
480 NEXT
490 TX=1
500 GOTO 360
510 RETURN
520 LINE(BX,BY)-(BX+1,BY),PRESET
530 BY=BY+1
540 BX=BX-(INT((30-BY)/10))
550 LINE(BX,BY)-(BX+1,BY),PSET
560 S=INT(BY/3)
570 IF S<>OS THEN SOUNDS,10
580 OS=S
590 IF BY=28 THEN610
600 RETURN
610 FOR S=1 TO 3
620 FOR Q=1 TO 0 STEP-1
630 LINE(BX,29)-(BX-3,24),PRESET,Q
640 LINE(BX,29)-(BX  ,24),PRESET,Q
650 LINE(BX,29)-(BX+3,24),PRESET,Q
660 NEXTQ
670 NEXTS
680 BA=0
690 E =TX+3:E=ABS(E -BX)
700 IF E>5 THEN 730
710 SOUND 5,5
720 H=H+1
730 LOCATE 0,2
740 PRINT H;"OUT OF";B
750 FOR T=1 TO 10
760 GOSUB 180
770 GOSUB 370
780 NEXT T
790 LOCATE 0,2:PRINT"             "
800 IF INKEY$="" THEN RETURN
810 GOTO 800
820 CLS
830 PRINT"AIR PATROL":PRINT
840 PRINT"You are a jet"
850 PRINT"pilot.";
860 IF INKEY$="" THEN 860
870 CLS
880 PRINT"Your mission:"
890 PRINT"bomb tanks!!"
900 PRINT"Use any key to"
910 PRINT"drop bomb";
920 IF INKEY$="" THEN 920
930 RETURN